;______________________________________
;           GESTION DE TEMPERATURE
; Matériel : 	ATtiny 85 16,5MHz 5V
; 				DS18B20
; (c) sammy76.free.fr
;V1.0 Sauvegarde dans l'EEPROM 
;sans controle de nbr de bytes
;V2.0 Sauvegarde dans la FLASH
;______________________________________
;ATtiny85 - 16.5MHz Digispark
;P0 : 
;P1 : SENSELED (Interne) 
;P2 : 
;P3 : DATA DS18X20
;P4 : 
;P5 :
.define F_CPU 16500000 ;16.5MHz
;FUSE H:FE, E:DD, L:E1
;w lfuse 0 0xe1
;w hfuse 0 0xdd
;w efuse 0 0xfe

.CSEG
.include "../includes/tn85def.inc"

.dseg
	SerialNumber:	.byte 8 ; 28fff8206b140472 pour mon DS18B20
;	tempC:			.byte 9 ;9 bytes
	
.cseg
.def 	A 		=r16			; GENERAL PURPOSE ACCUMULATOR
.def 	crc 	=r20		;CRC
.def 	DATA	=R18			; Data to EEPROM ou FLASH ou SRAM
.equ  	SENSELED=PORTB1   ;  SENSELED pin (Output on AVR)
.equ 	mesure_temps=5	; les mesures toutes les X min
.equ 	time_wait=(mesure_temps*60)/8	;mettre 225 (x8S) pour 30min *******************************************************
;ZH:ZL  EEPROM
;YH:YL	DDRAM

	.org 0000
;************************************************
;* Interrupt Vectors				      *
;************************************************
zRESET:		; Reset Handler
	rjmp	ON_RESET
zINT0addr:		; External Interrupt 0
	reti
zPCI0addr:		; Pin change Interrupt Request 0
	reti
zOC1Aaddr:		; Timer/Counter1 Compare Match 1A
	reti
zOVF1addr:		; Timer/Counter1 Overflow
	reti
zOVF0addr:		; Timer/Counter0 Overflow
	reti
zERDYaddr:		; EEPROM Ready
	reti
zACIaddr:		; Analog comparator
	reti
zADCCaddr:		; ADC Conversion ready
	reti
zOC1Baddr:		; Timer/Counter1 Compare Match B
	reti
zOC0Aaddr:		; Timer/Counter0 Compare Match A
	reti
zOC0Baddr:		; Timer/Counter0 Compare Match B
	reti
zWDTaddr:		; Watchdog Time-out
	rjmp WDTinterrupt
zUSI_STARTaddr:	; USI START
	reti
zUSI_OVFaddr:		; USI Overflow
	reti
;______________________________________
;           SETUP
;______________________________________
ON_RESET:
	ldi A, LOW(RAMEND)        	;Setup of stack pointer 0x15F t45/0x25F t85
	out SPL, A
	ldi A, HIGH(RAMEND)
	out SPH, A
	;Eteint le CAN
	cbi	ADCSRA, ADEN		;switch Analog to Digitalconverter OFF

	rcall	WDT_off				;Stop le watchdog
	
	ldi		A, (1<<SENSELED)
	out		DDRB, A        		; Set output pins
	
	cli
	ldi 	YL, LOW(tempC)
	ldi		YH, HIGH(tempC)			; Load to Y address of tempC table
resetLoop:
	rcall 	OWReset                   	; One wire reset
	brts  	resetLoop                  	; If device not present go to MainLoop
	
	rcall 	OWReadRom					; One Wire ReadRom[33h]
	brne  	resetLoop                  	; if not equal, jump to MainLoop (bad CRC)
	;rcall	CLIGNOTE
MainLoop:
	rcall 	OWReset
	rcall	OWMatchRom					; One Wire Match Rom [55h] Select
	rcall 	OWConvertT					; Convert T [44h]
OWbusy:
	rcall 	OWReset                   	; One wire reset
	brts  	OWbusy                  	; If device not present go to OWbusy
	rcall	OWMatchRom					; One Wire Match Rom [55h]
	rcall	OWReadScratchpad 			; Read Scratchpad [BEh]	
MAINWAIT:
	
	ldi		A,time_wait			;225x8S pour 30min 
	ldi		A,1
BOUCLE:
;Pause du watchdog (8s)
	Push A
	rcall	WDT_on			; Watchdog on
	ldi		A,(1<<SE)		; Enable sleep mode
	out		MCUCR, A
	sei						; Interrupt enable
	sleep					; On dort et on attend le watchdog

	cli						; Interrupt disable
	ldi		A,(0<<SE)      	; Disable sleep mode
	out		MCUCR, A
	Pop A
	dec      A            ; 1   Decrement counter
	brne    BOUCLE 

	;rcall 	CLIGNOTE		;Clignote tout les watchdogs supprimer pour économie d'énergie
	rjmp  MainLoop                  ; jump to MainLoop
;__________________________________________________________________
;Read Rom [33h]  Lance lecture de l'adresse 1wire
;Stock l'adresse sur l'EEPROM 0:0
;__________________________________________________________________
OWReadRom:
	ldi 	ZL, LOW(SerialNumber)		;
	ldi		ZH, HIGH(SerialNumber)		; Load to Y address of SerialNumber table
	ldi   	DATA, 0x33                 ; Write ReadRom command/With just one 1wire
	rcall 	OWWriteByte               ;
	rcall 	CRC8Init                  ; Initialize CRC8 value
	rcall 	OWReadByte                ; Read first byte (Family ID)
	cpi   	DATA, 0                     ; If first byte equal to zero, go to MainLoop
	breq  	MainLoop                  ; (short circuit on one wire bus)
	rcall 	CRC8Update                ; Update the CRC
	st		Z+, DATA					; Store first byte to table, and increment pointer
	ldi   	r17, 7                    ; 7 bytes remaining
StoreLoop:
	rcall 	OWReadByte                ; read next byte
	rcall 	CRC8Update                ; update the CRC
	st		Z+, DATA					; store next byte to table, and increment pointer
	dec   	r17                       ; decrement loop counter
	brne  	StoreLoop                 ; if greater than zero, jump to StoreLoop
	rcall 	GetCRC8                   ; Read computed CRC8
	cpi   	DATA,0                     ; compare it with zero
	ret
;__________________________________________________________________
; Match ROM [55h] Sélectionne le composant 1wire
;__________________________________________________________________
OWMatchRom: 
	ldi 	ZL, LOW(SerialNumber)
	ldi		ZH, HIGH(SerialNumber)		; Load to Y address of SerialNumber table
	ldi		DATA, 0x55 				;Match ROM
	rcall	OWWriteByte
	ldi   	r17, 8
LoadLoop:
	ld		DATA,Z+
	rcall 	OWWriteByte
	dec   	r17                      ; decrement loop counter
	brne  	LoadLoop                 ; if greater than zero, jump to LoadLoop
	ret
	
;__________________________________________________________________
; Convert T [44h] Lance la conversion de température
;__________________________________________________________________
OWConvertT: 
	ldi		DATA, 0x44 				;Convert T
	rcall	OWWriteByte
	sbi		OW_PORT, OW_DQ 			;enable strong pullup
	sbi		OW_DDR, OW_DQ
	;Attendre 750ms mini pour conversion
	ldi		A,255
	rcall	WaitMiliseconds
	ldi		A,255
	rcall	WaitMiliseconds
	ldi		A,255
	rcall	WaitMiliseconds
	cbi		OW_DDR, OW_DQ 		;disable strong pullup
	cbi		OW_PORT, OW_DQ
	ret
;__________________________________________________________________
; Read Scratchpad [BEh] lit les températures
;__________________________________________________________________
OWReadScratchpad:
	ldi		DATA, 0xBE 				;Read Scratchpad
	rcall	OWWriteByte
	;Sauve toute les données
	;rcall 	CRC8Init
	;ldi   	r17, 8
Loaddata:
	rcall 	OWReadByte                ; read next byte
	rcall	sauvegarde			  	;Save TEMPERATURE LSB
	adiw	YH:YL,1
	rcall 	OWReadByte                ; read next byte
	rcall	sauvegarde				;Save TEMPERATURE MSB
	adiw	YH:YL,1
	ret
;__________________________________________________________________
	
.include	"1-wire.asm"
.include	"crc8_v2.asm"
.include	"wait.asm"
.include	"../utils/watchdog.asm"
.include	"sauvegarde.asm"
;-------- CLIGNOTE
CLIGNOTE:
	SBI   	PORTB,SENSELED	;Allume LED
	ldi		A,1
	rcall	waitseconds		;Timing: false:1clks, true:2clks						   
	CBI   	PORTB,SENSELED	;Eteins LED
	ldi		A,1
	rcall	waitseconds		;Timing: false:1clks, true:2clks						   
	
	ret
;------------------------------------------------------------------------------
; End of file
;------------------------------------------------------------------------------
; Interruption du timeout du watchdog. On retourne simplement juste après le "sleep" !
WDTinterrupt:
	reti



.ESEG
	.org 0x0
;SerialNumber: 
;	.db 0,0,0,0,0,0,0,0	  ;8 bytes
tempC:
;	.db 0
;	,0,0,0,0,0,0,0,0,0 ;9 bytes

.org 0xc0
buildtime:
.db "sammy76.free.fr DS1820"
.db "V1.0:%DAY%.%MONTH%.%YEAR% %HOUR%:%MINUTE%"

.org 0xfd
memsave:
.db 03,00,0xFF ;FD FE FF ;Sauvegarde à partir de 0x300